/// @ 0.1
### {
    name: "Friends translator"
    version: "0.1"
    author: "@Varpie@peculiar.florist"
    description: "A plugin to automatically translate posts from specific people."
    permissions: []
    config: {
        debug: {
            type: "boolean"
            label: "Enable Debugging"
            description: "Write debugging information to the console."
            default: yes
        }
        listName: {
            type: "string"
            label: "List name"
            description: "Name of the list containing accounts you want to automatically translate"
            default: "Translation"
        }
        targetLang: {
            type: "string"
            label: "Target language"
            description: "The language in which the notes should be translated. Default value: en-US"
            default: "en-US"
        }
    }
}

@debug(comment) {
    ? (Plugin:config.debug = yes) {
        $comment <- Arr:join(["🔌 Plugin (Friends translator): " comment])
        print(comment)
    }
}

@translate(note) {
    debug(note.text)
    $translation <- Mk:api("notes/translate", {noteId: note.id, targetLang: Plugin:config.targetLang})
    $noteText <- Arr:join([note.text "
    
    *Translated from " translation.sourceLang ":*
    " translation.text])
    debug(noteText)
    note.text <- noteText
    note
}

$userIds <- []

@handler(note_) {
    ? (Arr:incl(userIds, note_.userId) = yes) {
        debug("Note from list found!")
        note_ <- translate(note_)
    }
    note_
}

$userLists <- Mk:api("users/lists/list", {})
~~ (#userList, userLists) {
    ? (userList.name = Plugin:config.listName) {
        userIds <- userList.userIds
    }
}

Plugin:register_note_view_interruptor(handler)